<!--#include file="kenshu.inc"-->
<%
Dim intKenshuCode, strDateFrom, strDateTo, strDateShime, strCheck, strShainCode

If Request.Cookies("kenshu")("CODE") = "" then
    '---- クッキーがなければ認証エラー画面表示 ----
    Call DispError("","")

Else
    '---- 共通ヘッダ表示 ----
    Call DispHeader("申込者一覧", "")

    intKenshuCode = Request.Form("KenshuCode")

    '---- 研修内容表示 ----
    Call DispKenshu

    '---- 受講可否の更新 ----
    If Request.Form("Toroku") = "1" Then

        '---- 受講可否決定(申込データを更新)----
        Call UpdateMoshikomi

        Response.Write "<H3>以下の通りに受講可否を決定しました。</H3>"
    End If

    '---- 申込者を一覧表示 ----
    Call DispMoshikomi

    '---- 研修一覧へ戻るボタン ----
    Call DispButton

    '---- 共通フッタ表示 ----
    Call DispFooter("1")

End if


'**************************************
'研修内容表示
'**************************************
Sub DispKenshu()

    '---- 検索クエリー ----
    strSQL = "SELECT * FROM 研修データ A, 社員マスタ B " & _
            "WHERE A.研修コード = '" & intKenshuCode & "' " & _
            "AND A.講師コード = B.社員コード"

    objRec.Open strSQL, objDBCon

    '---- 日付を表示用に変換 ----
    Call EditDispDate(objRec, strDateFrom, strDateTo, strDateShime)
%>
<table border="0" BGCOLOR="<%=GRND%>">
    <tr>
        <th bgcolor="<%=GRNH%>">研修コード</td>
        <td><%=intKenshuCode%></td>
    </tr>
    <tr>
        <th bgcolor="<%=GRNH%>">研修名称</td>
        <td><%=Server.HTMLEncode(objRec.Fields("研修名称").Value)%></td>
    </tr>
    <tr>
        <th bgcolor="<%=GRNH%>">日程</td>
        <td><%=strDateFrom & strDateTo%></td>
    </tr>
    <tr>
        <th bgcolor="<%=GRNH%>">時間</td>
        <td><%=objRec.Fields("時間").Value%></td>
    </tr>
    <tr>
        <th bgcolor="<%=GRNH%>">場所</td>
        <td><%=Server.HTMLEncode(objRec.Fields("場所").Value)%></td>
    </tr>
    <tr>
        <th bgcolor="<%=GRNH%>">定員</td>
        <td><%=objRec.Fields("定員").Value%></td>
    </tr>
    <tr>
        <th bgcolor="<%=GRNH%>">講師</td>
        <td><%=Server.HTMLEncode(objRec.Fields("氏名漢字").Value)%></td>
    </tr>
    <tr>
        <th bgcolor="<%=GRNH%>">申込締切日</td>
        <td><%=strDateShime%></td>
    </tr>
</table>
<hr>
<%
    objRec.Close

End Sub


'**************************************
'受講可否決定(申込データを更新)
'**************************************
Sub UpdateMoshikomi()

    objDBCon.BeginTrans

    '---- 検索クエリー ----
    strSQL = "SELECT 社員コード, 状態コード, 更新者コード FROM 申込データ " & _
            "WHERE 研修コード = " & intKenshuCode

    objRec.Open strSQL, objDBCon, 1, 2
    objRec.MoveFirst

    Do While Not objRec.EOF
        '---- 状態コードの変更 ----
        If Request.Form(objRec.Fields("社員コード")) = "on" Then
            objRec.Fields("状態コード").Value = "11"
        Else
            objRec.Fields("状態コード").Value = "12"
        End If
        objRec.Fields("更新者コード").Value = Request.Cookies("kenshu")("CODE")
        objRec.Update
        objRec.MoveNext
    Loop
    objRec.Close

    objDBCon.CommitTrans

End Sub


'**************************************
'申込者を一覧表示
'**************************************
Sub DispMoshikomi()

    '---- 検索クエリー ----
    strSQL = "SELECT * FROM 申込データ A, 社員マスタ B, 組織マスタ C, 状態マスタ D " & _
            "WHERE A.研修コード = " & intKenshuCode & " " & _
            "AND A.社員コード = B.社員コード " & _
            "AND B.組織コード = C.組織コード " & _
            "AND A.状態コード = D.状態コード " & _
            "ORDER BY B.組織コード, A.社員コード"

    objRec.Open strSQL, objDBCon, 3

    If objRec.EOF And objRec.BOF Then
        Response.Write "該当するレコードはありませんでした。"
        objRec.Close
        Exit Sub
    End If
%>
    <h3><%=objRec.RecordCount%> 人の社員がこの研修に申し込んでいます。</h3>
    <form action="kenshu04.asp" method="post">
    <table border="1" bgcolor="<%=YLWD%>">
        <tr bgcolor="<%=YLWH%>">
            <th nowrap>社員コード</th>
            <th nowrap>社員名</th>
            <th nowrap>所属部</th>
            <th nowrap>状態</th>
<%            If Request.Form("ShoriCode") = "3" Then
%>                 <th nowrap>受講可</th>
                <input type="hidden" name="KenshuCode" value="<%=intKenshuCode%>">
                <input type="hidden" name="ShoriCode" value="3">
                <input type="hidden" name="Toroku" value="1">
<%            End If
        Response.Write "</TR>"

        objRec.MoveFirst
        Do While Not objRec.EOF
            If objRec.Fields("状態コード").Value = "11" Then
                strCheck = " checked"
            Else
                strCheck = ""
            End If
%>
            <tr>
                <td><%=objRec.Fields("社員コード").Value %></td>
                <input type="hidden" name="ShainCode" value="<%=objRec.Fields("社員コード").Value %>">
                <td><%=objRec.Fields("氏名漢字").Value & "(" & objRec.Fields("氏名カナ").Value & ")"%></td>
                <td><%=Server.HTMLEncode(objRec.Fields("組織名").Value)%></td>
                <td><%=Server.HTMLEncode(objRec.Fields("状態名").Value)%></td>
<%                 If Request.Form("ShoriCode") = "3" Then
                    Response.Write "<TD align=""center""><INPUT type=""checkbox"" name=""" & objRec.Fields("社員コード").Value & """" & strCheck & "></TD>"
                End If
            Response.Write "</TR>"
            objRec.MoveNext
        Loop
    Response.Write "</TABLE>"
    objRec.Close

    If Request.Form("ShoriCode") = "3" Then
%>        <font size="+1">上記内容を<input type="submit" value="登録">します。</font>
<%    End If
    Response.Write "</FORM><BR>"

End Sub
%>