;*************************************************************************
;    Copyright 2004 Hata Akihiro 
;
;    　第5章　ＰＩＣアイデア集
;	5−１　１個の入力ポートでトリマ位置を読み込む。
;-------------------------------------------------------------------------
;プログラムの説明
;＜概要＞
;　シュミットトリガ・インバータによる発振器を利用したトリマ位置読み込みのテストプログラム。
;
;＜動作＞
;　０．１秒周期でＲＡ０のパルスのＬレベルを計測し、トリマ位置を読み込む。
;　読み込んだトリマ位置のバイナリ値をポートＢに出力する。
;
;-------------------------------------------------------------------------
;
; 2004/08/23	V1.00	初回リリース 
;
;
;
;
;-------------------------------------------------------------------------
;     CONFIGRATION FUSE
;	 WDT:Disable	OSC:Int RC     Code Protect:OFF    Power up timer:ON
;     OSCILLATOR
;        4MHz
;*************************************************************************
;
	LIST    P=PIC16F628A, R=DEC         ;Target Processor
	INCLUDE P16F628A.INC
;
	__CONFIG	_BODEN_OFF & _WDT_OFF & _INTOSC_OSC_NOCLKOUT & _CP_OFF & _PWRTE_ON & _DATA_CP_OFF & _LVP_OFF & _MCLRE_OFF
	__idlocs	H'0100'				;V1.00 2004/08/23
;	
;-------------------------------------------------------------------------
; DEFINE I/O Port
;-------------------------------------------------------------------------
; PortA
;	RA0		input
;	RA1		input				
;	RA2		input
;	RA3		input
;	RA4		input
;	RA5		input
;
; PortB
;	RB0	LED LSB	output
;	RB1	LED	output
;	RB2	LED	output
;	RB3	LED	output
;	RB4	LED	output
;	RB5	LED	output
;	RB6	LED	output
;	RB7	LED MSB	output
;
;-------------------------------------------------------------------------
; Variables
;-------------------------------------------------------------------------
;
;
;
;-------------------------------------------------------------------------
; Registers
;-------------------------------------------------------------------------
;
CNT0 		EQU	H'20'		; Counter for Wait Time
CNT1		EQU	H'21'		; Counter for Wait Time
COUNTER		EQU	H'22'		; Counter for TRIMER Meas. 
;-------------------------------------------------------------------------
; Program code
;-------------------------------------------------------------------------
;
	ORG	H'00'          		; Power ON
		GOTO	INITIALIZE	; 
;
;-------------------------------------------------------------------------
; Initialize
;-------------------------------------------------------------------------
INITIALIZE
		BSF	STATUS,RP0
		MOVLW	B'11111111'     	; Set I/O Port INPUT/OUTPUT
		MOVWF	TRISA
		MOVLW	B'00000000'
		MOVWF	TRISB
		BCF	STATUS,RP0
		MOVLW	H'FF'
		MOVWF	CMCON		; Set CMCON

;----------------------
;  OUTPUT Initialize
;----------------------

		MOVLW	B'00000000'
		MOVWF	PORTB

;*******************************************************
; MAIN PROGRAM
;*******************************************************
MAIN
		CALL	TRIMER
		MOVF	COUNTER,W
		MOVWF	PORTB
		CALL	WAIT100M		; Fix Wait Call
		GOTO	MAIN
;
;*******************************************************
;  SUBROUTINES
;*******************************************************
TRIMER
		CLRF	COUNTER
		BTFSS	PORTA,0
		GOTO	$-1
		BTFSC	PORTA,0
		GOTO	$-1
		INCF	COUNTER,F
		NOP
		BTFSS	PORTA,0
		GOTO	$-3		
		RETURN
;
WAIT1M					; 1msec Wait
		MOVLW	100
		MOVWF	CNT0
		NOP
		GOTO	$+1
		GOTO	$+1
		GOTO	$+1
		DECFSZ	CNT0,F
		GOTO	$-5
		RETURN
WAIT100M					; 100msec Wait
		MOVLW	100
		MOVWF	CNT1
		CALL	WAIT1M
		DECFSZ	CNT1,F
		GOTO	$-2
		RETURN
;
		END