;*************************************************************************
;    Copyright 2004 Hata Akihiro 
;
;    　第5章　ＰＩＣアイデア集
;	5−３　２個の出力ポートで８個のＬＥＤを点灯させる。
;-------------------------------------------------------------------------
;プログラムの説明
;＜概要＞
;　７４ＨＣ１６４によるＬＥＤ８個点灯のテストプログラム。
;
;＜動作＞
;　０．２秒周期でＣＯＵＮＴＥＲをインクリメントしたバイナリ値をＬＥＤで表示。
;　
;
;-------------------------------------------------------------------------
;
; 2004/08/23	V1.00	初回リリース 
;
;
;
;
;-------------------------------------------------------------------------
;     CONFIGRATION FUSE
;	 WDT:Disable	OSC:Int RC     Code Protect:OFF    Power up timer:ON
;     OSCILLATOR
;        4MHz
;*************************************************************************
;
	LIST    P=PIC16F628A, R=DEC         ;Target Processor
	INCLUDE P16F628A.INC
;
	__CONFIG	_BODEN_OFF & _WDT_OFF & _INTOSC_OSC_NOCLKOUT & _CP_OFF & _PWRTE_ON & _DATA_CP_OFF & _LVP_OFF & _MCLRE_OFF
	__idlocs	H'0100'				;V1.00 2004/08/23
;	
;-------------------------------------------------------------------------
; DEFINE I/O Port
;-------------------------------------------------------------------------
; PortA
;	RA0	CLK	output  to 74HC164
;	RA1	A	output　to 74HC164				
;	RA2		input
;	RA3		input
;	RA4		input
;	RA5		input
;
; PortB
;	RB0		input
;	RB1		input
;	RB2		input
;	RB3		input
;	RB4		input
;	RB5		input
;	RB6		input
;	RB7		input
;
;-------------------------------------------------------------------------
; Variables
;-------------------------------------------------------------------------
;
;
;
;-------------------------------------------------------------------------
; Registers
;-------------------------------------------------------------------------
;
CNT0 		EQU	H'20'		; Counter for Wait Time
CNT1		EQU	H'21'		; Counter for Wait Time
COUNTER		EQU	H'22'		; Counter for LED Disp.
LED_DATA		EQU	H'23'		; LED DATA
LOOP_CNT		EQU	H'24'		; Loop Counter  
;-------------------------------------------------------------------------
; Program code
;-------------------------------------------------------------------------
;
	ORG	H'00'          		; Power ON
		GOTO	INITIALIZE	; 
;
;-------------------------------------------------------------------------
; Initialize
;-------------------------------------------------------------------------
INITIALIZE
		BSF	STATUS,RP0
		MOVLW	B'11111100'     	; Set I/O Port INPUT/OUTPUT
		MOVWF	TRISA
		MOVLW	B'11111111'
		MOVWF	TRISB
		BCF	STATUS,RP0
		MOVLW	H'FF'
		MOVWF	CMCON		; Set CMCON

;----------------------
;  OUTPUT Initialize
;----------------------

		MOVLW	B'00000000'
		MOVWF	PORTA
		CLRF	COUNTER

		MOVLW	B'11111111'
		MOVWF	LED_DATA
		CALL	LED8SET		; LED All off
		CALL	WAIT200M		; Wait 200msec

;*******************************************************
; MAIN PROGRAM
;*******************************************************
MAIN
		INCF	COUNTER,F		; Incriment COUNTER
		COMF	COUNTER,W
		MOVWF	LED_DATA		; Load COUNTER to LED_DATA
		CALL	LED8SET		; Set LED
		CALL	WAIT200M		; Wait 200msec
		GOTO	MAIN
;
;*******************************************************
;  SUBROUTINES
;*******************************************************
LED8SET
		MOVLW	8
		MOVWF	LOOP_CNT
LED8_LOOP
		RLF	LED_DATA,F
		BTFSS	STATUS,C
		GOTO	$+3
		BSF	PORTA,1		; Set data 1
		GOTO	$+3
		BCF	PORTA,1		; Set data 0
		NOP
		BSF	PORTA,0		; CLK Pulse
		NOP
		BCF	PORTA,0
		DECFSZ	LOOP_CNT,F	; Loop Count
		GOTO	LED8_LOOP
		BCF	PORTA,1
		RETURN
;
WAIT1M					; 1msec Wait
		MOVLW	100
		MOVWF	CNT0
		NOP
		GOTO	$+1
		GOTO	$+1
		GOTO	$+1
		DECFSZ	CNT0,F
		GOTO	$-5
		RETURN
WAIT200M					; 200msec Wait
		MOVLW	200
		MOVWF	CNT1
		CALL	WAIT1M
		DECFSZ	CNT1,F
		GOTO	$-2
		RETURN
;
		END