;*************************************************************************
;    Copyright 2004 Hata Akihiro 
;
;    　第5章　ＰＩＣアイデア集
;	5−４　トリマで周波数を調整可能な簡易のこぎり波発振器 
;-------------------------------------------------------------------------
;プログラムの説明
;＜概要＞
;　簡易のこぎり波発振器のテストプログラム。
;
;＜動作＞
;　電源ＯＮでのこぎり波を連続出力する。
;　また、ＲＡ０から同じ周波数のパルスを発生する。
;
;-------------------------------------------------------------------------
;
; 2004/08/23	V1.00	初回リリース 
;
;
;
;
;-------------------------------------------------------------------------
;     CONFIGRATION FUSE
;	 WDT:Disable	OSC:Int RC     Code Protect:OFF    Power up timer:ON
;     OSCILLATOR
;        4MHz
;*************************************************************************
;
	LIST    P=PIC16F628A, R=DEC         ;Target Processor
	INCLUDE P16F628A.INC
;
	__CONFIG	_BODEN_OFF & _WDT_OFF & _INTOSC_OSC_NOCLKOUT & _CP_OFF & _PWRTE_ON & _DATA_CP_OFF & _LVP_OFF & _MCLRE_OFF
	__idlocs	H'0100'				;V1.00 2004/08/23
;	
;-------------------------------------------------------------------------
; DEFINE I/O Port
;-------------------------------------------------------------------------
; PortA
;	RA0		output
;	RA1		input				
;	RA2		input
;	RA3		input
;	RA4		input
;	RA5		input
;
; PortB
;	RB0		output/input
;	RB1		input
;	RB2		input
;	RB3		input
;	RB4		input
;	RB5		input
;	RB6		input
;	RB7		input
;
;-------------------------------------------------------------------------
; Variables
;-------------------------------------------------------------------------
;
;
;
;-------------------------------------------------------------------------
; Registers
;-------------------------------------------------------------------------
;
ST_TEMP 		EQU	H'20'		; Status Reg. Temp. for Interupt
W_TEMP		EQU	H'21'		; Work Reg. Temp. for Interupt

;-------------------------------------------------------------------------
; Program code
;-------------------------------------------------------------------------
;
	ORG	H'00'          		; Power ON
		GOTO	INITIALIZE	; 
;
	ORG	H'04'			; Go Interupt
		GOTO	INTERUPT
;-------------------------------------------------------------------------
; Initialize
;-------------------------------------------------------------------------
INITIALIZE

		BSF	STATUS,RP0
		MOVLW   B'11111111'     	; EXT INT Rising Edge
		MOVWF	OPTION_REG
		MOVLW   B'11111110'     	; Set I/O Port INPUT/OUTPUT
		MOVWF	TRISA
		MOVLW	B'11111110'
		MOVWF	TRISB
		BCF	STATUS,RP0
		MOVLW	H'FF'
		MOVWF	CMCON		; Set CMCON

;----------------------
;  OUTPUT Initialize
;----------------------
		MOVLW	B'00000000'
		MOVWF	PORTA
		MOVLW	B'00000000'
		MOVWF	PORTB

;*******************************************************
; MAIN PROGRAM
;*******************************************************
MAIN
		NOP			;discharge CAPACITOR
		NOP
		NOP
		NOP
		BSF	INTCON,INTE	;EXT INT Enable
		BSF	INTCON,GIE	;Global INT Enable
		BSF	STATUS,RP0	;BANK1
		BSF	TRISB,0		;Set RB0 INPUT
		BCF	STATUS,RP0	;BANK0

ENDLESS_LOOP
		GOTO	ENDLESS_LOOP
;
;*******************************************************
;  INTERUPT
;*******************************************************
INTERUPT
;****  save W register & status register
		MOVWF	W_TEMP		;save w reg
		SWAPF	STATUS,W		;status to wreg
		MOVWF	ST_TEMP		;save status
;
		BCF	PORTB,0
		BSF	STATUS,RP0
		BCF	TRISB,0		;Set RB0 OUTPUT
		BCF	STATUS,RP0
		BCF	PORTB,0
		NOP			;discharge CAPACITOR
		NOP
		NOP
		NOP
		BSF	STATUS,RP0
		BSF	TRISB,0		;Set RB0 INPUT
		BCF	STATUS,RP0
		BSF	PORTA,0		;make pulse
		NOP
		NOP
		BCF	PORTA,0		
		BCF	INTCON,INTF
;****  register restore and return
		SWAPF	ST_TEMP,W		;get saved status
		MOVWF	STATUS
		SWAPF	W_TEMP,F		;get saved wreg  
		SWAPF	W_TEMP,W
		RETFIE
;
		END